RETURN expression;

RETURN 後面跟表示式，會終止函式並將 expression 的值返回給呼叫者。此形式用於不返回集合的 PL/pgSQL 函式。

在返回標量型別的函式中，表示式的結果將自動轉換為函式的返回型別，如賦值部分所述。但要返回複合（行）值，您必須編寫一個提供完全請求列集的表示式。這可能需要使用顯式轉換。

如果您宣告的函式帶有輸出引數，則只需編寫 RETURN，後面不跟表示式。輸出引數變數的當前值將被返回。

如果您宣告的函式返回 void，則可以使用 RETURN 語句提前退出函式；但不要在 RETURN 後面寫表示式。

函式的返回值不能未定義。如果控制在未遇到 RETURN 語句的情況下到達函式頂層塊的末尾，將發生執行時錯誤。但是，此限制不適用於帶有輸出引數的函式和返回 void 的函式。在這些情況下，如果頂層塊結束，將自動執行 RETURN 語句。

一些例子

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

當 PL/pgSQL 函式宣告為返回 SETOF sometype 時，處理方式略有不同。在這種情況下，要返回的單個項由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然後使用一個不帶引數的最終 RETURN 命令來指示函式已執行完畢。RETURN NEXT 可與標量和複合資料型別一起使用；對於複合結果型別，將返回整個結果“表”。RETURN QUERY 將執行查詢的結果追加到函式的返回集中。RETURN NEXT 和 RETURN QUERY 可以在單個集合返回函式中自由混合使用，在這種情況下，它們的輸出將連線起來。

RETURN NEXT 和 RETURN QUERY 實際上並不會從函式返回——它們只是將零行或多行追加到函式的返回集中。然後，執行將繼續 PL/pgSQL 函式中的下一個語句。隨著連續的 RETURN NEXT 或 RETURN QUERY 命令的執行，結果集將被構建起來。最終的 RETURN（應不帶引數）會導致控制退出函式（或者您可以讓控制到達函式末尾）。

RETURN QUERY 有一個變體 RETURN QUERY EXECUTE，它指定要動態執行的查詢。引數表示式可以透過 USING 插入到計算出的查詢字串中，這與普通 EXECUTE 命令中的方式相同。

如果您宣告的函式帶有輸出引數，則只需編寫 RETURN NEXT，後面不跟表示式。每次執行時，輸出引數變數的當前值將被儲存，以便最終作為結果集中的一行返回。請注意，您必須將函式宣告為返回 SETOF record（當有多個輸出引數時），或 SETOF sometype（當只有一個型別為 sometype 的輸出引數時），才能建立帶有輸出引數的集合返回函式。

以下是一個使用 RETURN NEXT 的函式示例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

以下是一個使用 RETURN QUERY 的函式示例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 語句是最簡單的 IF 形式。如果條件為真，則執行 THEN 和 END IF 之間的語句。否則，將跳過它們。

示例：

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 語句在 IF-THEN 的基礎上增加了功能，允許您指定當條件不為真時應執行的替代語句集。（請注意，這包括條件評估為 NULL 的情況。）

示例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有時會存在兩個以上的選擇。IF-THEN-ELSIF 提供了一種方便的方法來依次檢查多個選項。IF 條件按順序測試，直到找到第一個為真的條件。然後執行關聯的語句，之後控制傳遞到 END IF 之後的下一個語句。（任何後續的 IF 條件將 不會 進行測試。）如果所有 IF 條件都不為真，則執行 ELSE 塊（如果存在）。

以下是一個例子

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

關鍵字 ELSIF 也可以拼寫為 ELSEIF。

另一種完成相同任務的方法是巢狀 IF-THEN-ELSE 語句，如下面的示例所示

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

然而，這種方法需要為每個 IF 編寫匹配的 END IF，因此當存在許多選項時，它比使用 ELSIF 更加麻煩。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

簡單形式的 CASE 基於運算元的相等性提供條件執行。search-expression 被（僅一次）計算，並依次與 WHEN 子句中的每個 expression 進行比較。如果找到匹配項，則執行相應的 statements，然後控制傳遞到 END CASE 之後的下一個語句。（後續的 WHEN 表示式不會被評估。）如果未找到匹配項，則執行 ELSE statements；但如果 ELSE 不存在，則會引發 CASE_NOT_FOUND 異常。

以下是一個簡單的例子

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

搜尋式形式的 CASE 基於布林表示式的真偽提供條件執行。WHEN 子句的每個 boolean-expression 按順序評估，直到找到一個產生 true 的表示式。然後執行相應的 statements，然後控制傳遞到 END CASE 之後的下一個語句。（後續的 WHEN 表示式不會被評估。）如果沒有找到真結果，則執行 ELSE statements；但如果 ELSE 不存在，則會引發 CASE_NOT_FOUND 異常。

以下是一個例子

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

這種形式的 CASE 與 IF-THEN-ELSIF 完全等價，除了規則是：到達一個省略的 ELSE 子句會引發錯誤，而不是什麼都不做。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定義一個無條件迴圈，該迴圈將無限重複，直到被 EXIT 或 RETURN 語句終止。可選的 label 可以被巢狀迴圈內的 EXIT 和 CONTINUE 語句使用，以指定這些語句引用哪個迴圈。

EXIT [ label ] [ WHEN boolean-expression ];

如果沒有給出 label，則終止最內層迴圈，並接著執行 END LOOP 之後的語句。如果給出了 label，則它必須是當前或某個外層巢狀迴圈或塊的標籤。然後，指定的迴圈或塊將被終止，並且控制將繼續執行迴圈/塊的相應 END 之後的語句。

如果指定了 WHEN，則僅當 boolean-expression 為真時才會發生迴圈退出。否則，控制將傳遞到 EXIT 之後的語句。

EXIT 可用於所有型別的迴圈；它不限於用於無條件迴圈。

當與 BEGIN 塊一起使用時，EXIT 將控制傳遞到塊末尾之後的下一個語句。請注意，為此目的必須使用標籤；未標記的 EXIT 永遠不會被視為匹配 BEGIN 塊。（這是對 PostgreSQL 8.4 之前的版本的更改，當時允許未標記的 EXIT 匹配 BEGIN 塊。）

示例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果沒有給出 label，則開始最內層迴圈的下一次迭代。也就是說，迴圈體中剩餘的所有語句都將被跳過，並且控制將返回到迴圈控制表示式（如果存在）以確定是否需要另一次迴圈迭代。如果存在 label，則它指定了將繼續執行的迴圈的標籤。

如果指定了 WHEN，則僅當 boolean-expression 為真時才會開始迴圈的下一次迭代。否則，控制將傳遞到 CONTINUE 之後的語句。

CONTINUE 可用於所有型別的迴圈；它不限於用於無條件迴圈。

示例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

WHILE 語句在 boolean-expression 評估為真時重複執行一系列語句。表示式在每次進入迴圈體之前進行檢查。

例如

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

此形式的 FOR 建立一個迴圈，該迴圈在整數值範圍內迭代。變數 name 被自動定義為 integer 型別，並且僅在迴圈內部存在（在迴圈內部，忽略該變數名的任何現有定義）。給出範圍的下限和上限的兩個表示式在進入迴圈時被評估一次。如果未指定 BY 子句，則迭代步長為 1，否則為 BY 子句中指定的值，該值在迴圈進入時被評估一次。如果指定了 REVERSE，則在每次迭代後減去步長值，而不是加。

整數 FOR 迴圈的一些示例

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大於上限（在 REVERSE 的情況下小於），則根本不執行迴圈體。不會引發錯誤。

如果 label 附加到 FOR 迴圈，則可以使用帶標籤的限定名稱引用整數迴圈變數。

異常處理程式經常需要識別發生的特定錯誤。PL/pgSQL 中獲取當前異常資訊有兩種方法：特殊變數和 GET STACKED DIAGNOSTICS 命令。

在異常處理程式中，特殊變數 SQLSTATE 包含與引發的異常相對應的錯誤程式碼（有關可能錯誤程式碼的列表，請參閱 Table A.1）。特殊變數 SQLERRM 包含與異常相關的錯誤訊息。這些變數在異常處理程式外部是未定義的。

在異常處理程式中，還可以透過使用 GET STACKED DIAGNOSTICS 命令來檢索當前異常的資訊，該命令的形式是

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每個 item 都是一個關鍵字，用於標識要分配給指定 variable 的狀態值（該變數應具有接收它的正確資料型別）。當前可用的狀態項顯示在 Table 41.2 中。

如果異常未為某個項設定值，則返回空字串。

以下是一個例子

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;